Introducció

L'objectiu d'aquesta pràctica és construir un full de càlcul que esculli números a l'atzar , sense repeticions, de l'1 al 99. Aquest full pot tenir aplicacions tan diverses com la simulació de loteries del tipus 6-49 o loteria primitiva, fins a la tria d'una mostra d'individus per respondre una enquesta. Per poder dur-ho a terme, haureu de treballar amb:

• Aprofundiment del tractament de l'atzar.

• Aplicació de les funcions de text al control de l'atzar.

• Ús de la combinació de tecles CTRL+Majúscules+F9 per executar fórmules.
  

El resultat podria ser similar a: 

Consideracions prèvies

Si us fixeu en la figura, la columna F està amagada. En aquesta columna es porten a terme uns càlculs auxiliars imprescindibles per al funcionament del full, tot i que, en la versió final, no cal que siguin visibles. Això també passa amb la columna I. En canvi, en aquest cas, s'ha fet servir un altre mètode d'ocultació de rètols i dades. En comptes d'amagar la columna, hem fet que el color de l'escriptura sigui igual que el color del fons. Per aquest motiu, sembla que la columna I estigui buida, però no és així, com tot seguit podreu comprovar. 

En aquesta pràctica apareixen funcions amb un funcionament més complex. És convenient que, per a una comprensió correcta del que fa cada funció, consulteu el menú ajuda quan apareguin.

Desenvolupament de la pràctica

• Afegiu al final del llibre un nou full de càlcul, anomeneu-lo Sorteig i desactiveu la visió de la quadrícula. 

• Entreu en les cel·les B2, B3, E2 i G2 els rètols corresponents i ajusteu l'amplada de les columnes el que convingui perquè hi càpiguen els rètols. No oblideu que la columna F encara no ha d'estar amagada. 

• Entreu en la cel·la I1 la fórmula següent, sense oblidar d'escriure el signe = i les cometes al començament i al final:

="0102030405060708091011121314151617181920
2122232425262728293031323334353637383940
4142434445464748495051525354555657585960
6162636465666768697071727374757677787980
81828384858687888990919293949596979899"

Tingueu en compte que si copieu directament l'expressió anterior, arrossegareu uns espais en blanc que no han de ser-hi: els de final de línia. Així, per evitar aquests espais en blanc, és millor que la copieu d'aquí, on ja s'han eliminat:

="010203040506070809101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899"

Una altra forma de procedir és copiar directament la fórmula sencera en la cel·la en qüestió, cel·la I1, i eliminar manualment aquests espais. En qualsevol cas, assegureu-vos bé que no els hi teniu.

Com podeu observar, aquí teniu escrits els nombres naturals fins al 99 fent servir dues xifres per a cadascun i posats entre cometes perquè tot sigui considerat com una paraula o cadena de text.

Entreu els nombres de les cel·les C2 i C3. El nombre de la cel·la C2 indicarà quin és l'últim nombre que entra en el sorteig, i el de la cel·la C3 fixa quants nombres no repetits cal triar a l'atzar. Evidentment, per a un correcte funcionament, C3 ha de ser més petit o igual que C2. 

• Entreu en la cel·la I2 la fórmula =ESQUERRA(I1;C2*2). 


Si varieu el contingut de la cel·la C2 comprovareu que la fórmula anterior "retalla", de tota la cadena de la cel·la I1, el tros que conté els nombres desitjats.

Busqueu informació sobre les funcions ESQUERRA i DRETA.
 

• Entreu el nombre 1 en la cel·la E3. 

• Entreu en la cel·la F3 la fórmula =ALEATENTRE(1;C$2). 
  

  La fórmula anterior escriurà un nombre enter, escollit a l'atzar, situat entre l'1 i el que indiqui C2.

• Entreu en la cel·la G3 la fórmula =VALOR(MIG( I2;(F3-1)*2+1;2)). 

Aquesta fórmula extraurà de la cadena I2 les dues xifres situades al lloc indicat per la cel·la F3 i les traduirà a valor numèric.

Busqueu informació sobre les funcions VALOR i MIG.
 

• Entreu en la cel·la I3 la fórmula següent: 

=ESQUERRA(I2;(F3-1)*2)&DRETA(I2;LONG(I2)-F3*2).


Aquesta fórmula escriurà la mateixa cadena que hi havia a I2, però sense que figuri la representació del nombre que ja ha sortit abans. D'aquesta manera, s'evita que hi hagi repeticions.

Busqueu informació sobre la funció LONG.
 

• Entreu en la cel·la E4 la fórmula: 

=SI(FILES(E$3:E4)<=C$3;E3+1;"").

Aquesta fórmula, que després copiareu en les cel·les que estan per sota de l'actual, serveix per continuar comptant noves tries de nombres, tantes com el contingut de la cel·la C3 ho indiqui.


Busqueu informació sobre les funcions FILES i COLUMNES.
 

• Entreu en la cel·la F4 la fórmula: 

=SI(E4="";"";ALEATENTRE(1;C$2+1-E4)). 

Amb aquesta fórmula, si la cel·la E4 no és buida, es farà un nou sorteig, però tenint en compte que cada vegada hi ha un nombre menys entre els que encara no han sortit.  

• Entreu en G4 la fórmula: 

=SI(E4="";"";VALOR(MIG(I3;(F4-1)*2+1;2))). 

Si E4 no és buida, extraurà de la cadena I3 el nombre que ocupi el lloc indicat pel sorteig efectuat a F4 i li donarà un valor numèric. Els nombres que van sortint en aquesta columna són escollits a l'atzar, però, gràcies a les altres fórmules de les cel·les veïnes, s'eviten les possibles repeticions.


• Entreu en I4 la fórmula: 

=SI(E4="";"";ESQUERRA(I3;(F4-1)*2)&DRETA(I3; LONG(I3)-F4*2)). 

Té el mateix efecte que la fórmula de la cel·la I3, sempre que la cel·la E4 no estigui buida.


• Seleccioneu el rang E4:I4 i copieu el seu contingut, arrossegant la selecció, sobre el rang E5:I101. D'aquesta manera, es podrà escollir un màxim de 99 números diferents. 

• Entreu 12 i 5 en les cel·les C2 i C3, respectivament. Cada cop que premeu la combinació de tecles CTRL+Majúscules+F9 es farà una nova tria a l'atzar de nombres amb les característiques indicades en les cel·les C2 i C3. 

• Seleccioneu la cel·la C2, accediu a Data | Validesa i feu que només s'hi puguin entrar nombres enters de l'1 al 99. Cal que surti un missatge d'error.

• Seleccioneu la cel·la C3 i, amb Data | Validesa, feu que només s'hi puguin entrar nombres enters de l'1 al que s'hagi entrat a C2. Per això, cal que en la pestanya Criteri s'hagi entrat Nombres enters (Nombres Complets) a Permet, entre a Dades, 1 a Minimum i  C2 a Màxim. Cal que surti també el corresponent missatge d'error.

• Canvieu els valors de C2 i C3 i premeu la combinació de tecles CTRL+Majúscules+F9 més cops. Provoqueu que surti algun missatge d'error.

• Amagueu la columna F. 

• Seleccioneu la columna I. Ara fareu invisible el contingut d'aquesta columna sense esborrar-lo: activeu Format | Cel·les | Efectes de lletra | Color: blanc.

• Seleccioneu el rang B2:B3 i feu que tingui un fons blau amb les lletres blanques.

• Feu el mateix amb el rang E2:G2. 

• Apliqueu un fons groc clar en els rangs C2:C3 i E3:G101. 

• Protegiu les cel·les que creieu convenients. 

• Deseu el llibre.

Ampliacions, aclariments i comentaris

Seleccioneu el rang B2:C3 i afegiu-hi una quadrícula de color blau

• Activeu Format | Cel·les | Vores i seleccioneu un contorn de color blau.

Seleccioneu el rang B2:B3 i feu que tingui un fons blau amb les lletres blanques

• Activeu Format | Cel·les | Fons | Color: blau. 

• Activeu Format | Cel·les | Efectes de lletra | Color: blanc.