Introducció

En aquesta pràctica treballareu:

• Les funcions de text.
• Protecció de fulls de càlcul.

El full de càlcul OpenOffice Calc disposa d'un gran nombre de funcions per al tractament d'informació de tipus textual. L'objectiu de la pràctica és donar a conèixer algunes d'aquestes funcions. El full de càlcul proposat fa algunes composicions de tipus geomètric a partir d'una paraula donada. El full proposat és el següent:

Les funcions utilitzades són ESQUERRA, DRETA, MIG, LONG i REPT. 

La sintaxi de les funcions és la següent:
 

ESQUERRA(<Text>;<Nombre de caràcters>): retorna el nombre de caràcters indicats situats a l'esquerra de la cadena text. 

DRETA(<Text>;<Nombre de caràcters>): retorna el nombre de caràcters indicats situats a la dreta de la cadena text. 

MIG(<Text>;<Posició inicial>;<Nombre de caràcters>): retorna el nombre de caràcters indicats de la cadena text a partir de la posició inicial indicada. 

LONG (<Text>): ofereix el nombre de caràcters del text. 

REPT(<Text>;<Nombre de repeticions>): retorna el text repetit tantes vegades com indica el nombre de repeticions.

També s'utilitza l'operador de concatenació & que permet obtenir una cadena ajuntant-ne dues.

La pràctica ha estat dissenyada per a paraules amb un màxim d'11 caràcters. Funciona correctament amb paraules més curtes, però no més llargues.

Preparatius inicials

• Creeu un nou full del llibre MODUL2. Anomeneu-lo Paraules. 
• Dimensioneu les columnes perquè A tingui 0,70 cm, B i C 2,70, D 2,90, E 5 i F 2,70. 
• Introduïu els rètols de les cel·les A1 (Jocs amb paraules) i B3 (Paraula:).
• Seleccioneu el rang  A1:F1 i accediu a Format | Fusiona les cel·les i a Format | Cel·les | Alineament i trieu l'opció Centre del desplegable Horitzontal.
• Introduïu una paraula a la cel·la C3 que servirà com a dada de partida per al funcionament del full; per exemple, "VARIABLE". 
• Introduïu la seqüència de nombres 1...11 al rang A5:A15.

 

• Introduïu a la cel·la B5 la fórmula =ESQUERRA(C$3;A5) que extraurà de la paraula "VARIABLE" el nombre de caràcters per l'esquerra indicat a la cel·la A5 (1 en aquest cas). 

Si llegiu aquest document per pantalla podeu seleccionar la fórmula a introduir de la pantalla, copiar-la (Ctrl + C) i enganxar-la (Ctrl + V) a la cel·la corresponent del full de càlcul.

• Copieu la fórmula de la cel·la B5 sobre el rang B6:B15. 
• Si voleu interrompre la seqüència quan s'ha arribat a la paraula més llarga mantenint l'aspecte de triangle, heu de modificar la fórmula utilitzada i preveure aquesta situació. Modifiqueu la fórmula de la cel·la B5 perquè sigui  =SI(LONG(C$3)>=A5;ESQUERRA(C$3;A5);""), situant el cursor a la línia de fórmules i teclejant el text necessari. Si treballeu llegint aquest document de l'ordinador, també podeu copiar la fórmula del text i enganxar-la a la línia de fórmules. 
• Copieu la fórmula anterior sobre el rang B6:B15.

 

Per obtenir aquest efecte de triangle invertit, a mesura que avancen de fila en fila, el nombre de caràcters ha de ser inferior. Per aquesta raó, el contingut del comptador de la columna A ha d'aparèixer restant en comptes de sumant. L'expressió LONG(C$3)-A5+1 a la cel·la C5 inicial donarà inicialment el nombre total de caràcters de la paraula i anirà disminuint fila a fila fins a 1. 

• Introduïu a la cel·la C5 la fórmula =ESQUERRA(C$3;LONG(C$3)-A5+1) i copieu-la sobre el rang C6:C15. Observeu els resultats. 
• Heu de preveure, igual que a la primera part, el funcionament amb paraules de menys d'11 caràcters. Per aquesta raó, modifiqueu les fórmules introduïdes preveient aquesta situació: modifiqueu la fórmula de la cel·la C5 perquè sigui =SI(LONG(C$3)+1-A5>0;ESQUERRA(C$3;LONG(C$3)-A5+1);"") i copieu-la sobre el rang C6:C15. Observeu-ne els resultats.

 

L'efecte proposat a aquesta part és que la paraula va desapareixent per la dreta i apareixent per l'esquerra. Per obtenir-ho, heu de fer una composició dels efectes obtinguts als apartats anteriors. La fórmula a incloure a la cel·la D5 ha de contenir els següents elements: 

DRETA(C$3;A5-1), que ofereix el final de la paraula i a cada fila obteniu un caràcter més. 

" " espai en blanc de separació 

ESQUERRA(C$3;LONG(C$3)-A5+1), que ofereix l'inici de la paraula i a cada fila obteniu un caràcter menys. 

El condicional SI(LONG(C$3)>=A5;;), que controla el correcte funcionament per paraules de menys d'11 caràcters.

• La fórmula de la cel·la D5 ha de ser:

=SI(LONG(C$3)>=A5;DRETA(C$3;A5-1)&" "&ESQUERRA(C$3;LONG(C$3)-A5+1);""). Copieu-la sobre el rang D6:D15 i observeu-ne els resultats.

El camí proposat per obtenir l'efecte de la columna E és el següent: el contingut de cada cel·la s'obté a partir de la cel·la anterior afegint un asterisc i una nova lletra de la paraula utilitzada; la primera cel·la ha d'incloure el primer caràcter de la paraula. 

• Introduïu a la cel·la E5 la fórmula =ESQUERRA(C3;1). 
• La fórmula de la cel·la E6 ha de ser: 

=SI(LONG(C$3)>=A6;E5&"*"&MIG(C$3;A6;1);""). Copieu-la sobre el rang E7:E15 i observeu-ne els resultats.

Cinquena part

L'efecte que es pot observar a la columna F s'aconsegueix repetint les lletres tantes vegades com el lloc que ocupen a la paraula de la cel·la C3.

• Entreu a la cel·la F5 la fórmula =ESQUERRA(C3;1).
• Entreu a la cel·la F6 la fórmula =SI(LONG(C$3)>=A6;REPT(MIG(C$3;A6;1);A6);"").

Mentre el nombre de caràcters de la paraula inicial sigui més gran o igual que l'indicat per A6, es repetirà el caràcter que ocupa el lloc indicat per A6 tantes vegades com indica A6.

• Copieu aquesta fórmula sobre el rang F7:F15.

Part final

• Seleccioneu el rang B5:F15 i apliqueu-li el tipus de lletra Courier new. 
• Doneu un fons verd pastel al rang A1:F16. 
• Doneu un fons blanc a la cel·la C3. 
• Dibuixeu una vora negra envoltant el rang A1:F16.
• Desactiveu la visió de la quadrícula.  
• Enregistreu el llibre. 
• Modifiqueu la paraula de la cel·la C3 i observeu-ne els resultats.

Protecció del full

Moltes vegades és convenient protegir els continguts de les cel·les d'un full de càlcul contra possibles esborrats accidentals. És clar que només s'hauran de protegir aquelles cel·les que l'usuari no ha de modificar en l'ús habitual del full.

En el vostre cas, voleu que la cel·la C3 sigui accessible per entrar-hi noves paraules i que totes les altres estiguin protegides, de tal manera que no es puguin modificar des del teclat. Per fer-ho:

• Seleccioneu la cel·la C3, activeu el menú Format | Cel·les | Protecció de cel·les, desactiveu l'opció Protegit de l'esmentat quadre de diàleg i premeu D'acord.
• Activeu el menú Eines | Protegeix el document | Full i premeu D'acord dins del quadre de diàleg Protegeix el full sense incloure una contrasenya a aquesta protecció.
• Enregistreu el llibre. 

Intenteu modificar el contingut d'una cel·la bloquejada i d'una altra no bloquejada i analitzeu-ne el resultat.